通达信“动能突破”主图指标公式--资金背离
更多指标：http://www.macd888.com(macd888股票论坛）一、公式解析
指标是结合资金动向与 MACD 的波段操作工具，
核心看点：一是资金流向直观，通过主动买、主动卖计算出的净流入万，用红柱标注资金流入、绿柱标注流出，若股价创 20 天新高但资金却创 20 天新低，会标 “价升量减”，提示量价背离，大概率要回调，需及时止盈。
二是底部信号出现 “MACD 底背” 文字时，说明股价下跌但 MACD 指标拐头向上，是底部确认的关键信号，底背离出现后 1-20 天内，只要出现放量大阳（涨幅超 3%、量能放大 1.5 倍）且突破 20 天前高，就会标 “入场” 红字 + 图标，这是波段启动的买点，绿色点状阻力位、红色点状支撑位自动标注，到支撑位且资金流入可低吸，到阻力位且资金流出可高抛。
二、公式如下
DRAWTEXT_FIX(1,0.005,0,0,'所属风格:'),COLORMAGENTA;
DRAWTEXT_FIX(1,0.06,0,0,FGBLOCK),COLORYELLOW;
DRAWTEXT_FIX(1,0.005,0.05,0,'所属概念:'),COLORMAGENTA;
DRAWTEXT_FIX(1,0.06,0.05,0,GNBLOCK),COLORYELLOW;
DRAWKLINE(HIGH, OPEN, LOW, CLOSE);
AAV:=VOL/((HIGH-LOW)*2-ABS(CLOSE-OPEN));
主动买:=IF(CLOSE>OPEN, AAV*(HIGH-LOW), IF(CLOSE<OPEN, AAV*((HIGH-OPEN)+(CLOSE-LOW)), VOL/2));
主动卖:=IF(CLOSE>OPEN, 0-AAV*((HIGH-CLOSE)+(OPEN-LOW)), IF(CLOSE<OPEN, 0-AAV*(HIGH-LOW), -VOL/2));
净流入万:(主动买 + 主动卖)/10000, NODRAW;
MACD_DIF:=EMA(CLOSE,12)-EMA(CLOSE,26);
MACD_DEA:=EMA(MACD_DIF,9);
ZYG13:=BARSLAST(REF(CROSS(MACD_DIF, MACD_DEA),1));
MACD底背信号:=REF(CLOSE, ZYG13+1)>CLOSE AND REF(MACD_DIF, ZYG13+1)<MACD_DIF AND CROSS(MACD_DIF, MACD_DEA);
DRAWTEXT(MACD底背信号, LOW*0.98, 'MACD底背'), COLOR00FFFF;
底背后天数:=BARSLAST(MACD底背信号);
前高:=HHV(HIGH,20);
放量大阳:=C>O AND VOL>REF(VOL,1)*1.5 AND (C-REF(C,1))/REF(C,1)*100>3;
突破前高:=C>REF(前高,1);
入场信号:=底背后天数>=1 AND 底背后天数<=20
AND 放量大阳
AND 突破前高;
价格新高:=HIGH>=HHV(HIGH, 20);
资金新低:=净流入万<=LLV(净流入万, 20) AND 净流入万<0;
DRAWTEXT(价格新高 AND 资金新低, HIGH*1.02, '价升量减'), COLORMAGENTA;
STICKLINE(净流入万>0, CLOSE, CLOSE+净流入万/1000, 0.5, 0), COLORRED;
STICKLINE(净流入万<0, CLOSE, CLOSE+净流入万/1000, 0.5, 0), COLORGREEN;
DRAWICON(入场信号, LOW*0.97, 1);
DRAWTEXT(入场信号, LOW*0.93, '入场'), COLORRED;
H1:=MAX(DYNAINFO(3), DYNAINFO(5));
L1:=MIN(DYNAINFO(3), DYNAINFO(6));
P1:=H1-L1;
阻力位:L1+P1*7/8, POINTDOT, COLORGREEN;
支撑位:L1+P1*0.5/8, POINTDOT, COLORRED;
页:
[1]